plugins {
    id 'java-library'
    id 'com.github.johnrengelman.shadow' version '8.1.1'
    id 'maven-publish'
}

subprojects {
    group = 'dev.tommyjs'
    version = '2.5.1'

    apply plugin: 'java-library'
    apply plugin: 'com.github.johnrengelman.shadow'
    apply plugin : 'maven-publish'

    publishing {
        publications {
            mavenJava(MavenPublication) {
                from(components["java"])
                pom {
                    name = project.name
                }
            }
        }

        repositories {
            maven {
                name = 'tommyjs'
                url = uri("https://repo.tommyjs.dev/repository/maven-releases/")
                credentials {
                    username = findProperty("tommyjsUsername") as String
                    password = findProperty("tommyjsPassword") as String
                }
            }
        }
    }

    tasks {
        build {
            dependsOn(tasks.shadowJar)
        }
    }

    repositories {
        mavenCentral()
    }

    dependencies {
        compileOnly 'org.jetbrains:annotations:24.1.0'
        implementation 'org.slf4j:slf4j-api:2.0.12'

        testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
        testImplementation 'io.projectreactor:reactor-core:3.6.4'
        testImplementation 'org.junit.jupiter:junit-jupiter:5.8.1'
        testImplementation 'ch.qos.logback:logback-classic:1.5.3'
    }

    test {
        useJUnitPlatform()
        testLogging {
            exceptionFormat = 'full'
            showStandardStreams = true
        }
    }

    java {
        sourceCompatibility = JavaVersion.VERSION_23
        targetCompatibility = JavaVersion.VERSION_23
        withSourcesJar()
    }
}